SPARQL endpoint

Accueil

Quelques exemples

Remarque : ces différents exemples sont tirés de l'explication détaillée des technologies du Web sémantique qui accompagne cette publication du thésaurus W.

Les URI, les vedettes en français et éventuellement l'URI équivalente dans Dbpedia de tous les concepts spécifiques de « 20e siècle »

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>

SELECT ?concept ?label ?focus WHERE {
  <http://$base/thesaurus/resource/T4-45> skos:narrower ?concept .
  ?concept skos:prefLabel ?label.
  OPTIONAL {?concept foaf:focus ?focus}
  FILTER (lang(?label)='fr')
}

Les URI et les vedettes en français de tous les concepts équivalents entre le thésaurus W et Rameau

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?conceptW ?labelW ?conceptRameau ?labelRameau WHERE {
  ?conceptW skos:exactMatch ?conceptRameau .
  ?conceptW skos:prefLabel ?labelW.
  ?conceptRameau skos:prefLabel ?labelRameau.
  FILTER (lang(?labelW)='fr')
  FILTER (lang(?labelRameau)='fr')
}

Tous les termes rejetés (ou étiquettes alternatives) du concept qui a pour étiquette en français « industrie du cuir »

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?altLabel WHERE {
  ?concept skos:prefLabel "industrie du cuir"@fr;
           skos:altLabel ?altLabel.
}

Les URI et les vedettes des concepts reliés à un concept spécifique du concept « Finances publiques »

PREFIX skos: <http://www.w3.org/2004/02/skos/core#>

SELECT ?conceptrelie ?labelrelie WHERE {
 	<http://localhost:8080/thesaurus/resource/T1-1222> skos:narrower ?concept.
	?concept skos:related ?conceptrelie.
	?conceptrelie skos:prefLabel ?labelrelie.
}